[ruby-list:22885] Re: またもや rd-mode.el

From: Toshiro Kuwabara <[e-mail]>
Subject: [ruby-list:22864] Re: またもや rd-mode.el
Date: Wed, 24 May 2000 00:01:49 +0900

るびきちです。

> ええっと、思い付かないですが、rd-view-modeとか。
> あとは他のバッファにLabelの一覧、とかLabelのabbrevとかですか。
> 難しそうなのばっかりですが。(^^;;

ちょい考えてみます。

> 自分でも書いたの忘れてましたが、もともとrd-cite-regionという

実は知っていました。
だけどうまくいかないから自前で製作してみたり。

> 僕の期待する動作の簡単なテストケースを用意しておきます。

rubyunit ブームで流行語なのかも(笑)<テストケース
と、とりあえずテストケースは通るようにできたので出しておきます。
バグフィックスもしておきました。

(defun rd-indent-line ()
  "Indent line as deep as prev line."
  (interactive "*")
  (let ((prev-indent (progn
		       (forward-line -1)
		       (rd-current-indentation))))
    (forward-line 1)
    (rd-indent-to prev-indent)
    (back-to-indentation)))

(defun rd-line-list-p ()
  "Whether the line is list or not."
  (save-excursion
    (beginning-of-line)
    (looking-at " *\\*")))

(defun rd-indent-to (num)
  (let (beg)
    (save-excursion
      (beginning-of-line)
      (setq beg (point))
      (back-to-indentation)
      (delete-region beg (point))
      (indent-to num))))

(defun rd-current-indentation ()
  ""
  (save-excursion
    (beginning-of-line)
    (looking-at " *\\(\\* +\\)?")
    (length (buffer-substring (match-beginning 0)(match-end 0)))))
  
(defun rd-cite-region (beg end)
  "Make region into Verbatim."
  (interactive "r*")
  (let (listp prev-indent indent)
    (save-excursion
      (goto-char beg)
      (forward-line -1)
      (setq listp (rd-line-list-p)
            prev-indent (rd-current-indentation))
      (forward-line 1)
      (setq indent (rd-current-indentation))
      (if listp (rd-indent-region beg end (+ prev-indent 2))
        (cond ((and (zerop prev-indent) (zerop indent))
               (rd-indent-region beg end 2))
              ((> prev-indent indent)
               (rd-indent-region beg end prev-indent))
              (t
               (goto-char end)))))))
  
(defun rd-indent-region (beg end &optional indent)
  "Make the indent of region deeper by INDENT."
  (interactive "r*")
  (setq indent (or indent 2))
  (save-excursion
    (goto-char beg)
    (while (< (point) end)
      (setq end (+ end indent))
      (insert-char ?  indent)
      (forward-line 1))))

(defun rd-yank-as-verbatim (&optional arg)
  (interactive "P")
  (let ((beg (point))
        (end (progn
               (yank)
               (point)))
        )
    (rd-cite-region beg end)
    (if arg (goto-char beg))))

(defun rd-insert-buffer-as-verbatim (buf)
  (interactive "bInsert buffer (verb): ")
  (insert-buffer buf)
  (rd-cite-region (point)(mark)))