[ruby-dev:6435] Re: wrong line number

新井です。

>>> From: [e-mail] (Yukihiro Matsumoto)
>>> Date: 22 Mar 1999 04:26:22 +0900
>>> Subject: [ruby-dev:6429] Re: wrong line number

> まつもと ゆきひろです

> |以下のスクリプトが出力する行番号がおかしいです。
> 
> なんだか，あちこちの行番号の調整が絡み合ってややこしいことに
> なってました．多分直せたと思います．

よろしくお願いします。ruby -d でデタラメなとこを参
照してしまうので。

> heredocではnodeの生成前に行番号を調整していたからです．なん
> か複雑ですね．

nodeのflagsを参照するgdbマクロってありませんかね？
nd_set_line()は複雑で、まだ追い切れてない。

rubyの型を出力するマクロは書いたんですけどね。
# 結構使えるので、最後に添付します。
# でも、まつもとさんとかがもっといいの書いてそうだな。

> |# どうも、私がrubyすると、バグに出会うようです。
> 
> すいません．ご迷惑でしょうが，私は大変感謝しています．
> 今後ともよろしく．

いえ、勉強になりますので、構わないです。
その代わり、rubyのソースを見る時間の方が長くなって
るけど(^^;

恥ずかしいけど、私の.gdbinitを添付します。
以下を.gdbinitに書くと、gdbで

(gdb) p str
$4 = 1074773748

(gdb) rp str
$5 = "T_STRING"
$6 = {basic = {flags = 7, klass = 1074818828}, len = 0, ptr = 0x810aa28 "", 
  orig = 0}

といった表示が得られます。
# gdbマクロにelif/elsifはないのだろうか？

define rp
  if ($arg0 & 0x1)
    print "FIXNUM"
  else
  if ($arg0 == 4)
    print "NIL"
  else
  if ($arg0 == 0)
    print "FALSE"
  else
  if ($arg0 == 2)
    print "TRUE"
  else
    set $rbasic = (struct RBasic*)$arg0
    set $flags = (*$rbasic).flags & 0xff
    if ($flags == 0x01)
      print "T_NIL"
    else
    if ($flags == 0x02)
      print "T_OBJECT"
      print *(struct RObject*)$rbasic
    else
    if ($flags == 0x03)
      print "T_CLASS"
      print *(struct RClass*)$rbasic
    else
    if ($flags == 0x04)
      print "T_ICLASS"
    else
    if ($flags == 0x05)
      print "T_MODULE"
    else
    if ($flags == 0x06)
      print "T_FLOAT"
      print *(struct RFloat*)$rbasic
    else
    if ($flags == 0x07)
      print "T_STRING"
      print *(struct RString*)$rbasic
    else
    if ($flags == 0x08)
      print "T_REGEXP"
      print *(struct RRegexp*)$rbasic
    else
    if ($flags == 0x09)
      print "T_ARRAY"
      print *(struct RArray*)$rbasic
    else
    if ($flags == 0x0a)
      print "T_FIXNUM"
    else
    if ($flags == 0x0b)
      print "T_HASH"
      print *(struct RHash*)$rbasic
    else
    if ($flags == 0x0c)
      print "T_STRUCT"
    else
    if ($flags == 0x0d)
      print "T_BIGNUM"
    else
    if ($flags == 0x0e)
      print "T_FILE"
      print *(struct RFile*)$rbasic
    else
    if ($flags == 0x20)
      print "T_TRUE"
    else
    if ($flags == 0x21)
      print "T_FALSE"
    else
    if ($flags == 0x22)
      print "T_DATA"
      print *(struct RData*)$rbasic
    else
    if ($flags == 0x23)
      print "T_MATCH"
    else
    if ($flags == 0xfd)
      print "T_VARMAP"
    else
    if ($flags == 0xfe)
      print "T_SCOPE"
    else
      print "Unknown"
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end
    end

  end
  end
  end
end

end
document rp
rubyデータの内容を表示する
end